Vă mulțumim pentru susținere

Actionscript 3 - Cea mai rapidă modalitate de a analiza yyyy-mm-dd hh: mm: ss la un obiect Date?

Am încercat să găsesc o modalitate foarte rapidă de a analiza yyyy-mm-dd [hh: mm: ss] într-un obiect Date. Iata cele 3 moduri pe care le-am incercat sa le fac si vremurile pe care le ia fiecare metoda pentru a parsa 50.000 de siruri de date date.

Știe cineva modalități mai rapide de a face acest lucru sau sfaturi pentru a accelera metodele?

castMethod1 takes 3673 ms 
castMethod2 takes 3812 ms 
castMethod3 takes 3931 ms

Cod:

private function castMethod1(dateString:String):Date {
    if ( dateString == null ) {
        return null;
    }

    var year:int = int(dateString.substr(0,4));
    var month:int = int(dateString.substr(5,2))-1;
    var day:int = int(dateString.substr(8,2));

    if ( year == 0 && month == 0 && day == 0 ) {
        return null;
    }

    if ( dateString.length == 10 ) {
        return new Date(year, month, day);
    }

    var hour:int = int(dateString.substr(11,2));
    var minute:int = int(dateString.substr(14,2));
    var second:int = int(dateString.substr(17,2));

    return new Date(year, month, day, hour, minute, second);
}

-

private function castMethod2(dateString:String):Date {
    if ( dateString == null ) {
        return null;
    }

    if ( dateString.indexOf("0000-00-00") != -1 ) {
        return null;
    }

    dateString = dateString.split("-").join("/");

    return new Date(Date.parse( dateString ));
}

-

private function castMethod3(dateString:String):Date {
    if ( dateString == null ) {
        return null;
    }

    var mainParts:Array = dateString.split(" ");
    var dateParts:Array = mainParts[0].split("-");

    if ( Number(dateParts[0])+Number(dateParts[1])+Number(dateParts[2]) == 0 ) {
        return null;
    }

    return new Date( Date.parse( dateParts.join("/")+(mainParts[1]?" "+mainParts[1]:" ") ) );
}

Nu, data.parse nu va ocupa liniuțe în mod implicit. Și trebuie să revin nul pentru șirurile de timp date ca "0000-00-00" .

0
adăugat editat

7 răspunsuri

Cred că Data.Parse () nu funcționează?

0
adăugat
nu-i asa! !
adăugat autor Marci-man

Ei bine, atunci metoda 2 pare cel mai bun mod:

private function castMethod2(dateString:String):Date {
    if ( dateString == null ) {
        return null;
    }

    if ( dateString.indexOf("0000-00-00") != -1 ) {
        return null;
    }

    dateString = dateString.split("-").join("/");

    return new Date(Date.parse( dateString ));
}
0
adăugat

Am folosit următorul snipplet pentru a analiza șirurile de date UTC:

private function parseUTCDate( str : String ) : Date {
    var matches : Array = str.match(/(\d\d\d\d)-(\d\d)-(\d\d) (\d\d):(\d\d):(\d\d)Z/);

    var d : Date = new Date();

    d.setUTCFullYear(int(matches[1]), int(matches[2]) - 1, int(matches[3]));
    d.setUTCHours(int(matches[4]), int(matches[5]), int(matches[6]), 0);

    return d;
}

Doar eliminați partea de timp și ar trebui să funcționeze bine pentru nevoile dvs.:

private function parseDate( str : String ) : Date {
    var matches : Array = str.match(/(\d\d\d\d)-(\d\d)-(\d\d)/);

    var d : Date = new Date();

    d.setUTCFullYear(int(matches[1]), int(matches[2]) - 1, int(matches[3]));

    return d;
}

No idea about the speed, I haven't been worried about that in my applications. 50K iterations in significantly less than a second on my machine.

0
adăugat
Spuneți-ne cât de mult au fost luate iterațiile de 50K pentru cele 3 funcții de exemplu, astfel încât să putem pune "mai puțin de o secundă" în perspectivă.
adăugat autor bzlm
Mă întreb dacă va exista o performanță suplimentară dacă înlocuiți potrivirile var și d cu cuvântul cheie const.
adăugat autor UnknownJoe

Aceasta a fost cea mai rapida pe care am putut sa o fac dupa cateva intrebari:

private function castMethod4(dateString:String):Date {          
    if ( dateString == null ) 
        return null;    
    if ( dateString.length != 10 && dateString.length != 19) 
        return null;

    dateString = dateString.replace("-", "/");
    dateString = dateString.replace("-", "/");

    return new Date(Date.parse( dateString ));
}

Imi fac itectii de 50k in aproximativ 470ms pentru castMethod2 () pe computerul meu si 300 ms pentru versiunea mea (aceeasi cantitate de lucru facuta in 63% din timp). Aș spune cu siguranță că ambele sunt "suficient de bune", dacă nu analizați cantități proaste de date.

0
adăugat

Dat fiind că Date.parse () nu acceptă toate formatele posibile, putem preforma valoarea date stringată date folosind DateFormatter cu formatString pe care Data.parse () o poate înțelege, de ex.

// English formatter
var stringValue = "2010.10.06"
var dateCommonFormatter : DateFormatter = new DateFormatter();
dateCommonFormatter.formatString = "YYYY/MM/DD";

var formattedStringValue : String = dateCommonFormatter.format(stringValue);                                
var dateFromString : Date = new Date(Date.parse(formattedStringValue));
0
adăugat
În loc să efectuați acești 2 pași, am putea folosi DateFormatter.parseDateString () .
adăugat autor approxiblue

Iată implementarea mea. Dă-o încercare.

public static function dateToUtcTime(date:Date):String {
  var tmp:Array = new Array();
  var char:String;
  var output:String = '';

  // create format YYMMDDhhmmssZ
  // ensure 2 digits are used for each format entry, so 0x00 suffuxed at each byte

  tmp.push(date.secondsUTC);
  tmp.push(date.minutesUTC);
  tmp.push(date.hoursUTC);
  tmp.push(date.getUTCDate());
  tmp.push(date.getUTCMonth() + 1); // months 0-11
  tmp.push(date.getUTCFullYear() % 100);


  for(var i:int=0; i < 6/* 7 items pushed*/; ++i) {
    char = String(tmp.pop());
    trace("char: " + char);
    if(char.length < 2)
      output += "0";
    output += char;
  }

  output += 'Z';

  return output;
}
0
adăugat
var strDate:String = "2013-01-24 01:02:40";

function dateParser(s:String):Date{
    var regexp:RegExp = /(\d{4})\-(\d{1,2})\-(\d{1,2}) (\d{2})\:(\d{2})\:(\d{2})/;
    var _result:Object = regexp.exec(s);

    return new Date(
        parseInt(_result[1]),
        parseInt(_result[2])-1,
        parseInt(_result[3]),
        parseInt(_result[4]),
        parseInt(_result[5]),
        parseInt(_result[6])
    );
}

var myDate:Date = dateParser(strDate);
0
adăugat